;******************************************************************************
;   This file is a basic template for assembly code for a PIC18F1220. Copy    *
;   this file into your project directory and modify or add to it as needed.  *
;                                                                             *
;   The PIC18FXXXX architecture allows two interrupt configurations. This     *
;   template code is written for priority interrupt levels and the IPEN bit   *
;   in the RCON register must be set to enable priority levels. If IPEN is    *
;   left in its default zero state, only the interrupt vector at 0x008 will   *
;   be used and the WREG_TEMP, BSR_TEMP and STATUS_TEMP variables will not    *
;   be needed.                                                                *
;                                                                             *
;   Refer to the MPASM User's Guide for additional information on the         *
;   features of the assembler.                                                *
;                                                                             *
;   Refer to the PIC18F1220/1320 Data Sheet for additional information on the *
;   architecture and instruction set.                                         *
;                                                                             *
;******************************************************************************
;                                                                             *
;    Filename: ipergate_V1.asm                                                *
;    Date: 2008                                                               *
;    File Version: V1                                                         *
;                                                                             *
;    Author: Emanuele Bonanni                                                 *
;    Company: EMCelettronica Srl                                              *
;                                                                             * 
;******************************************************************************
;                                                                             *
;    Files required:         P18F1220.INC                                     *
;                                                                             *
;******************************************************************************

	LIST P=18F1220		;directive to define processor
	#include 	;processor specific variable definitions

;******************************************************************************
;Configuration bits

    CONFIG	OSC = INTIO2 , WDT = OFF, LVP = OFF, FSCM = OFF, IESO = OFF, PWRT = ON, BOR = ON, 
    BORV = 27, MCLRE = ON, CP0 = ON, CP1 = ON 

;******************************************************************************
;Variable definitions

AUX				EQU	0x00
TIM	   		EQU	0x01				; General Purpose  
TIM1			EQU	0x02 
TIM2			EQU	0x03				; index SM storage received SMS
TIM3			EQU	0x04
;STATUS_TEMP	EQU	0x05
VOLTE1		EQU	0x06
VOLTE			EQU	0x07
SMS_INDEX	EQU	0x08
;					EQU	0x09
REG				EQU	0x0A
;WREG_TEMPEQU	0x0B
;BSR_TEMP	EQU	0x0C
INGR		EQU	0x0D	; Stato ingressi all'accensione AUTOAPPRENDIMENTO
					; INGR,1	-->	stato iniziale ingresso 1
					; INGR,2	--> stato iniziale ingresso 2
FLAG			EQU	0x0E
rele1			EQU	0x00
rele2			EQU	0x01
rele3			EQU	0x02
rele4			EQU	0x03
norisp		EQU	0x04
ring			EQU	0x05
stopfsr		EQU	0x06	
all				EQU	0x07

FLAG2			EQU	0x0F				; SMS 
impulso		EQU	0x00
attivo		EQU	0x01
disattivo	EQU	0x02
alarm1		EQU	0x03
alarm2		EQU	0x04


;RAM50		EQU	0x50				; tel.number	SMS rx		

;			EQU	0x6F			; tel.number 	max 32 cifre

;************************************************************************
; Buffer di risposta TELIT

RAM80		EQU	0x80
RAM81		EQU	0x81					; verifica OK	;O
RAM82		EQU	0x82					;K

RAM87		EQU	0x87

RAM8A		EQU	0x8A
RAM8B		EQU	0x8B
RAM8C		EQU	0x8C


;************************************************************************

;******************************************************************************

		#define	IN_1		PORTA,4	; Ingresso_1
		#define	IN_2		PORTA,1	; Ingresso_2

		#define	RELE1		PORTA,2	; Uscita RELE_1
		#define	RELE2		PORTA,7	; Uscita RELE_2
		#define	RELE3		PORTA,3	; Uscita RELE_3
		#define	RELE4		PORTA,6	; Uscita RELE_4

		#define	POWER_ON	PORTA,0	; Power on TELIT
		#define	RING_IND	PORTB,0	; Ring indicator TELIT

		#define	PWRCTRL		PORTB,2	; verifica Modulo ON , Power Control


_AT_		EQU		0x00			; AT
;_ATH_		EQU		0x08		; ATH
_ATE_		EQU		0x10			; ATE=0
_IPR_		EQU		0x20			; AT+IPR=9600	
_CMEE_		EQU		0x30		; AT+CMEE=1
_CSMP_		EQU		0x40
_CMGF_		EQU		0x54		; AT+CMGF=1
_CPIN_		EQU		0x60		; AT+CPIN
_CREG_		EQU		0x68		; AT+CREG
_CNMI_		EQU		0x70		; AT+CNMI=0,0,0,0,0
_FCLASS_	EQU		0x84		; 
_CLIP_		EQU		0x90
_CPAS_		EQU		0xA0
_CPBS_		EQU		0xB0

;******************************************************************************
;EEPROM data
; Data to be programmed into the Data EEPROM is defined here
; \r = carriage return   \n = new line (cr lf)
; usare \r (CR) come verifica di fine stringa!!!

;------------------------------------------------------------------------
;	Attenction command:	AT
;	Response:			OK
;------------------------------------------------------------------------
		ORG	0xf00000
		DE	"AT\r"	

;------------------------------------------------------------------------
;	ath		OK
;	HOOK	HANG-UP	attacca
;------------------------------------------------------------------------
;		ORG	0xf00008
;		DE	"ATH\r"
;
;------------------------------------------------------------------------
;	Disable command echo:	ATE=0
;	Response:				OK
;------------------------------------------------------------------------
		ORG	0xf00010
		DE	"ATE=0\r"
;
;------------------------------------------------------------------------
; Fix baude rate:	AT+IPR=9600
; Response:			OK
;------------------------------------------------------------------------
		ORG	0xf00020
		DE	"AT+IPR=9600\r"

;------------------------------------------------------------------------
;	Enable extended error code:	AT+CMEE=1
;	Response:					OK
;------------------------------------------------------------------------
		ORG	0xf00030
		DE	"AT+CMEE=1\r"

;------------------------------------------------------------------------
;
; 	
;------------------------------------------------------------------------
		ORG	0xf00040
		DE	"AT+CSMP=17,167,0,0\r"

;------------------------------------------------------------------------
;	SMS format type:	AT+CMGF=1
;	Response:			OK
;------------------------------------------------------------------------
		ORG	0xf00054
		DE	"AT+CMGF=1\r"

;------------------------------------------------------------------------
;	SIM presence checking:	AT+CPIN
;	Response:				+CPIN: READYOK
;------------------------------------------------------------------------
		ORG	0xf00060
		DE	"AT+CPIN\r"

;------------------------------------------------------------------------
; 	Network checking:	AT+CREG
;	Response:			+CREG: 0,1OK
;------------------------------------------------------------------------
		ORG	0xf00068
		DE	"AT+CREG\r"

;------------------------------------------------------------------------
;	New message unsolecited indicaiton:	AT+CNMI=0,0,0,0,0
;	Response:							OK
;------------------------------------------------------------------------
		ORG	0xf00070
		DE	"AT+CNMI=0,0,0,0,0\r"

;------------------------------------------------------------------------
;
;
;------------------------------------------------------------------------
		ORG	0xf00084
		DE	"AT+FCLASS=8\r"

;------------------------------------------------------------------------
;
;
;------------------------------------------------------------------------
		ORG	0xf00090
		DE	"AT+CLIP=1\r"

;------------------------------------------------------------------------
;
;
;------------------------------------------------------------------------
		ORG	0xf000A0
		DE	"AT+CPAS?\r"

;------------------------------------------------------------------------
;
;
;------------------------------------------------------------------------
		ORG	0xf000B0
		DE	"AT+CPBS=\"SM\"\r"

;******************************************************************************
;Reset vector
; This code will start executing when a reset occurs.

		ORG     0x0000    			; processor reset vector

		movlw	B'01101111'
		movwf	OSCCON
		goto    Setup				; go to beginning of program

;******************************************************************************
;High priority interrupt vector
; This code will start executing when a high priority interrupt occurs or
; when any interrupt occurs if interrupt priorities are not enabled.

		ORG	0x0008

		btfss	PIR1,RCIF			; Interrupt USART flag bit?
		goto	isrout				; no!
		bcf		PIR1,RCIF			; yes, clear and go ahead
		goto	ISR_routine

;******************************************************************************
;Low priority interrupt vector and routine

		ORG	0x0018
		retfie	FAST

;******************************************************************************

ISR_routine:				; isr_routine	RX serial_Data >> INDF0 (FSR)
		movf	RCREG,w				; Scarica RCREG
		btfsc	FLAG,stopfsr		; Incrementare FSR ?
		goto	isrout				; NO!

		movf	FSR0L,w					;\\
		xorlw	0xF1				; if 	FSR == 0xF1
		BNZ		isr1				; then	FSR == 0XF0
		decf	FSR0L
isr1:
		movf	RCREG,w
		xorlw	0x20;!				;  elimina gli spazi dalla rx
		BZ		isrout

		movf	RCREG,w
		xorlw	0x0A;!				;  elimina i ritorni a capo dalla rx
		BZ		isrout

		movff	RCREG,INDF0			; Carica INDF0 con RCREG
		incf	FSR0L,f				; Incrementa FSR

isrout:	
		retfie	FAST

;******************************************************************************
;******************************************************************************

Setup:
		clrf	BSR
		clrf	FSR0H
		clrf	FSR0L

		clrf	PORTA
		clrf	PORTB
		clrf	LATB
		setf	ADCON1

    movlw   B'00010010'		;	RA7     RA6     RA5	 RA4  RA3   RA2   RA1  RA0
   	movwf   TRISA 		;	RELE2	RELE4	MCLR IN_1 RELE3	RELE1 IN_2 POWER_ON
    movlw   B'11110111' 	;	RB7 RB6 RB5	 RB4  RB3   RB2   	RB1  RB0
    movwf   TRISB		;	RXD  GPLED	PWRCTRL	TXD  RING_IND

		clrf	ADCON0

; config isr

		clrf	INTCON2					; PortB pullup-on
		clrf	INTCON3
		clrf	PIE1
		clrf	PIE2
		clrf	PIR1
		clrf	PIR2
		clrf	IPR1						; all low priority
		clrf	IPR2						; all low priority
		clrf	RCON
;------------------------------------------------------------------------

		call	clear_ram				; clear ram
		call	set_baude_rate	; 9600 N 8 1 + enable uart_ISR

		movlw	b'11000000'			; set GIE,PEIE
		movwf	INTCON

;-------------------------------------------autoadetect IN_1 & IN_2

		bcf		INGR,1				; INGR,1=stato iniz.
		btfsc	IN_1					; ingresso_1
		bsf		INGR,1

		bcf		INGR,2				; INGR,2=stato iniz.;
		btfsc	IN_2					; ingresso_2
		bsf		INGR,2

;------------------------------------------------------------------------
setup1:
		call	t3s						; Stabilize power supply

;----------------------------------------------------activate Modulo TELIT

		btfsc	PWRCTRL				; modulo on?
		goto	setup1_1			; SI! go ahead

		bsf		POWER_ON			; Power_on / off
		call	t2s						; 2 Seconds Pulse
		bcf		POWER_ON
		goto	setup1				; verify if ON

;------------------------------------------------------------------------
setup1_1:
		call	t3s							; Stabilize on/off

		bcf		FLAG,stopfsr		; Enable ISR --> FSR inc
		btfsc	RCSTA,OERR			; check uart overrun
		call	uart_overrun		; restore

		movlw	_AT_
		call	ee_at				; at_command
		movlw	_IPR_
		call	ee_at				; fix port rate @ 9600
		movlw	_ATE_
		call	ee_at				; Disable command echo

		movlw	_CLIP_
		call	ee_at				; Enable calling line identification
		call	check_ok		; verify OK
		btfss	STATUS,Z		; Z=1 OK						
		goto	setup1			; error --> no_ok off/on modulo! 

		movlw	_CMEE_
		call	ee_at			; Enable extended error code =1 numeric
		movlw	_CPIN_
		call	ee_at			; SIM presence checking (PIN free) READY
		movlw	_CREG_
		call	ee_at			; Network checking x,1 (home) or x,5 (roaming)
		movlw	_CMGF_
		call	ee_at			; SMS format type 1=text
		movlw	_CNMI_
		call	ee_at		; DISABLE New message unsolecited indication +CMTI:
		movlw	_FCLASS_
		call	ee_at			; AT+FCLASS=8	Attiva Voice mode

		movlw	_CSMP_
		call	ee_at				; 17,167,0,0
		call	check_ok		; verify OK
		BNZ		setup1		; error --> no_ok spegni e riaccendi il modulo! 

; fare un contatore per setup2 e setup3 se dopo 30-60 secondi
; la SIM è ancora occupata, telit off

setup2:
		movlw	_CPBS_
		call	ee_at			; AT+CPBS="SM"	setta phonebook normal SIM
		call	check_ok		; verify OK
		BNZ		setup2			; error --> no_ok loop

setup3:
		movlw	'0'
		movwf	VOLTE1
		movlw	'1'	
		movwf	VOLTE
		call	clear_ram80
		call	_cpbr	; AT+CPBR=1	read phonebook position 1 only for setup SIM
		call	t1s	; 1+1 second? --- Basta leggere SIM 1 per setup???

		movf	RAM8A,w
		xorlw	':'
		BNZ		setup4			; SIM not busy

		movf	RAM8B,w
		xorlw	'1'
		BNZ		setup4			; SIM not busy

		movf	RAM8C,w
		xorlw	'4'
		BZ		setup3			; SIM busy retry

setup4:								; SIM not busy
		movlw	'1'
		movwf	SMS_INDEX		; in questo caso SMindex ininfluente
		call	clear_ram80
		bsf		FLAG,all		; delete all message ,4 SMindex don't care
		call	_cmgd				; delete sms
		bcf		FLAG,all
		call	t2s
		call	clear_ram80	; cancella ram 80

;************************************************************************
main:
		call	t1s

		bcf		FLAG,stopfsr; attiva FSR inc sotto ISR

		movlw	'0'			; preset SMS_INDEX for SMS READ SM 1-2-3
		movwf	SMS_INDEX

main_loop:
		btfsc	RCSTA,OERR	; check uart overrun
		call	uart_overrun; restore

		btfss	RING_IND		; Ring Indicator
		goto	wait_ring		; RING IN PROGRESS!

		incf	SMS_INDEX		; Read next SMS

		movlw	0x80				; Set FSR
		movwf	FSR0L

		call	_cmgr			; at+cmgr= (read sms)  SMS_INDEX = 

		bsf		FLAG,stopfsr; blocca FSR inc sotto ISR
		call	cmserror		; qui verificare +CMSERROR:321 quindi no sms

		btfss	STATUS,Z
		goto	main2		; Z=0 NON ricevuto +CMSERROR --> Cosa ho ricevuto?
						; Z=1 ricevuto +CMSERROR quindi no sms ma OK
		bcf		FLAG,stopfsr; attiva FSR inc sotto ISR

		movf	SMS_INDEX,w	; se SMS_INDEX = '3'
		xorlw	'3'
		BNZ		main_loop		; MAIN_LOOP

		call	statoz			; CONTROLLA STATO ZONE
		BNZ		alarmz			; Z=0 alarm zone
											; Z=1 ok
		goto	main				; TORNA AL MAIN

main2:
		call	checkcmgr		; qui verificare +CMGR:..... quindi sms
		btfss	STATUS,Z
		goto	setup1		; Z=0 NON ho ricevuto ne +CMSERROR ne +CMGR:
							; Z=1 Ricevuto +CMGR
		goto	wait_sms	; SMS! ricevuto +CMGR quindi SMS

;************************************************************************